• Logout
Bonhoeffer ICT

Bonhoeffer ICT

Veelvoorkomende vragen en antwoorden

Start-MagisterVenster

Het volgende VBscript start Magister Schoolwerkplek (Magister SWP) in een zo groot mogelijk venster, terwijl de Windows-taakbalk nog zichtbaar blijft. De gebruiker kan zo makkelijk schakelen tussen Magister in een RDP-sessie en andere applicaties. Dit script is in gebruik op Bonhoeffercollege, Castricum.

Het werkt door de afmetingen van het bureaublad te bepalen en dan de ideale afmetingen van de ExternBureaublad-venster te bereken, vervolgens MSTSC te starten met de juiste parameters.

Vragen: p [period] wiegmans [snail] bonhoeffer [period] nl

Start-Magistervenster.vbs

'''Start-MagisterVenster.vbs'''
'
'  Script start Magister in een RDP-sessie in een zo groot mogelijk venster 
'  zodat de taakbalk zichtbaar blijft! 
'
'  6 sept 2011 Paul Wiegmans (p.wiegmans@bonhoeffer.nl)
'
' 14 jan 2015: aangepast, goede bepaling van schermresolutie in Windows 8 en 8.1

' ======= AANPASSEN ! =======
sRDPbestand = "p:\algemeen\magister4\magister-swp.rdp"
'============================

Set objWMIService = GetObject("Winmgmts:\\.\root\cimv2")
iSchermBreedte = 0
iSchermhoogte = 0

' De waarden objItem.ScreenWidth en objItem.ScreenHeight hebben in Windows 8 geen waarde.
Set colItems = objWMIService.ExecQuery("Select * From Win32_DesktopMonitor",,48)
For Each objItem in colItems
    if objItem.ScreenWidth > 0 then
        iSchermBreedte = objItem.ScreenWidth
    end if
    If objItem.ScreenHeight > 0 then    
        iSchermhoogte = objItem.ScreenHeight
    end if
Next

if iSchermBreedte <= 0 or iSchermHoogte <= 0 then
    ' Alternatieve manier om in Windows 8 schermresolutie te bepalen
    Set colItems = objWMIService.ExecQuery("Select * from Win32_VideoController",,48)
    For Each objItem in colItems 
        iSchermBreedte = objItem.CurrentHorizontalResolution 
        iSchermhoogte = objItem.CurrentVerticalResolution
    Next
end if

' Bepalen ideale vensterafmetingen voor Windows (proefondervindelijk gevonden)
iVensterBreedte = iSchermBreedte - 6
iVensterHoogte = iSchermhoogte - 68

' Beperk extreme waarden tot een redelijk waarde
if iVensterBreedte > 1920 then
    iVensterBreedte = 1920
end if
if iVensterHoogte > 1080 then
    iVensterHoogte = 1080
end if

if iSchermBreedte <= 0 or iSchermHoogte <= 0 then
    ' Start met standaard instellingen, fullscreen of wat dan ook, bepaald door instellingen in RDP-bestand
    sMagisterCmd = "mstsc " & sRDPBestand
else
    ' Start RDP-sessie met opgegeven hoogte en breedte
    sMagisterCmd = "mstsc " & sRDPBestand & " /w:" & iVensterBreedte & " /h:" & iVensterHoogte
end if

Set oShell = CreateObject("WScript.Shell")
oShell.Run sMagisterCmd, 1, False

Het bovenstaande script gebruikt een bestand met instellingen voor de RDP-sessie, genaamd "magister-swp.rdp". Pas regel 10 van bovenstaand script aan je eigen situatie aan.

Magister-swp.rdp

Dit bestand bevat instellingen die door MSTSC (Terminal Server Client) wordt gebruikt. Het door ons gebruikte RDP-bestand is hieronder beschreven.

screen mode id:i:2
desktopwidth:i:1920
desktopheight:i:1080
session bpp:i:24
full address:s:bonhoeffer.swp.nl
compression:i:1
keyboardhook:i:2
audiomode:i:0
redirectdrives:i:0
redirectprinters:i:1
redirectcomports:i:0
redirectsmartcards:i:0
displayconnectionbar:i:1
autoreconnection enabled:i:1
alternate shell:s:
shell working directory:s:
disable wallpaper:i:1
disable full window drag:i:1
disable menu anims:i:1
disable themes:i:0
disable cursor setting:i:0
bitmapcachepersistenable:i:1
redirectclipboard:i:1
redirectposdevices:i:0
authentication level:i:0
prompt for credentials:i:0
negotiate security layer:i:1
remoteapplicationmode:i:0
allow desktop composition:i:0
allow font smoothing:i:0
gatewayhostname:s:
gatewayusagemethod:i:0
gatewaycredentialssource:i:4
gatewayprofileusagemethod:i:0
promptcredentialonce:i:1
drivestoredirect:s:*
use multimon:i:0
audiocapturemode:i:0
videoplaybackmode:i:1
connection type:i:2
redirectdirectx:i:1
use redirection server name:i:0
winposstr:s:0,3,0,0,800,600
networkautodetect:i:1
bandwidthautodetect:i:1
enableworkspacereconnect:i:0
rdgiskdcproxy:i:0
kdcproxyname:s:

Om een RDP-bestand te maken is het makkelijkst, om een leeg bestand aan te maken met de naam magister-dwp.rdp. Rechtsklik hierop en kies "Bewerken". Pas de instellingen naar eigen wens aan, zorg er in ieder geval voor dat je het adres van je schoolwerkplek {schoolnaam}.swp.nl invult en druk op [Opslaan].

Eigen aanpassingen aan RDP-bestand

Onderstaand zijn de belangrijkste instellingen die aangepast moeten worden aan je eigen situatie. Om dit met de hand te doen, wijzig met een teksteditor het RDP-bestand als volgt:

full address : het adres waarmee verbinding wordt gemaakt. In ons geval staat hier full address:s:bonhoeffer.swp.nl. Aanpassen!

drivestoredirect : koppelt lokale schijven. Belangrijk als je rapportages, exportbestanden e.d. wilt opslaan op je eigen schijf. De waarde die ervoor zorgt , dat al jouw lokale schijfkoppelingen in je RDP-sessie worden gerepliceerd, is drivestoredirect:s:*. Wil je alleen U: en V: aankoppelen in je RDP-sessie, gebruik drivestoredirect:s:U:;V:.

Links

Documentatie over de Remote Desktop instellingen is te lezen op MS Knowledgebase: Remote Desktop Protocol settings in Windows Server 2003 and in Windows XP. Een helder overzicht van RDP instellingen staat ook op Donkz.nl